gdritter repos farbfeld / master src / Image / Farbfeld.hs
master

Tree @master (Download .tar.gz)

Farbfeld.hs @master — raw · history · blame 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE RecordWildCards #-}

module Image.Farbfeld
  ( Image(..)
  , Pixel(..)
  , parseImage
  , emitImage
  ) where

import           Control.Monad (when, forM_)
import           Data.Array (Array, array, bounds, (!))
import           Data.ByteString.Lazy (ByteString)
import           Data.Word (Word16, Word32)
import qualified Data.Serialize as S

newtype Image = Image
  { imgPixels :: Array (Word32, Word32) Pixel
  } deriving (Eq, Show)

data Pixel = Pixel
  { pxRed   :: !Word16
  , pxGreen :: !Word16
  , pxBlue  :: !Word16
  , pxAlpha :: !Word16
  } deriving (Eq, Show)

parseImage :: ByteString -> Either String Image
parseImage = S.runGetLazy $ do
  magic <- S.getByteString 8
  when (magic /= "farbfeld") $
    fail "Unable to find farbfeld magic number"
  w <- S.getWord32be
  h <- S.getWord32be
  imgPixels <- array ((0, 0), (w-1, h-1)) <$> sequence
    [ sequence ((x, y), getPixel)
    | y <- [0..h-1]
    , x <- [0..w-1]
    ]
  return Image { .. }

emitImage :: Image -> ByteString
emitImage (Image pixels) = S.runPutLazy $ do
  S.putByteString "farbfeld"
  let (w, h) = snd (bounds pixels)
  S.putWord32be (w + 1)
  S.putWord32be (h + 1)
  forM_ [0..h] $ \y ->
    forM_ [0..w] $ \x -> do
      let Pixel { .. } = pixels ! (x, y)
      S.putWord16be pxRed
      S.putWord16be pxGreen
      S.putWord16be pxBlue
      S.putWord16be pxAlpha

getPixel :: S.Get Pixel
getPixel = Pixel
  <$> S.getWord16be
  <*> S.getWord16be
  <*> S.getWord16be
  <*> S.getWord16be